File: autoconf.info,  Node: Defining Symbols,  Next: Setting Output Variables,  Up: Results

7.1 Defining C Preprocessor Symbols
===================================

A common action to take in response to a feature test is to define a C
preprocessor symbol indicating the results of the test.  That is done by
calling ‘AC_DEFINE’ or ‘AC_DEFINE_UNQUOTED’.

   By default, ‘AC_OUTPUT’ places the symbols defined by these macros
into the output variable ‘DEFS’, which contains an option
‘-DSYMBOL=VALUE’ for each symbol defined.  Unlike in Autoconf version 1,
there is no variable ‘DEFS’ defined while ‘configure’ is running.  To
check whether Autoconf macros have already defined a certain C
preprocessor symbol, test the value of the appropriate cache variable,
as in this example:

     AC_CHECK_FUNC([vprintf],
       [AC_DEFINE([HAVE_VPRINTF], [1],
          [Define if vprintf exists.])])
     AS_IF([test "x$ac_cv_func_vprintf" != xyes],
       [AC_CHECK_FUNC([_doprnt],
          [AC_DEFINE([HAVE_DOPRNT], [1],
             [Define if _doprnt exists.])])])

   If ‘AC_CONFIG_HEADERS’ has been called, then instead of creating
‘DEFS’, ‘AC_OUTPUT’ creates a header file by substituting the correct
values into ‘#define’ statements in a template file.  *Note
Configuration Headers::, for more information about this kind of output.

 -- Macro: AC_DEFINE (VARIABLE, VALUE, [DESCRIPTION])
 -- Macro: AC_DEFINE (VARIABLE)
     Define VARIABLE to VALUE (verbatim), by defining a C preprocessor
     macro for VARIABLE.  VARIABLE should be a C identifier, optionally
     suffixed by a parenthesized argument list to define a C
     preprocessor macro with arguments.  The macro argument list, if
     present, should be a comma-separated list of C identifiers,
     possibly terminated by an ellipsis ‘...’ if C99-or-later syntax is
     employed.  VARIABLE should not contain comments, white space,
     trigraphs, backslash-newlines, universal character names, or
     non-ASCII characters.

     VALUE may contain backslash-escaped newlines, which will be
     preserved if you use ‘AC_CONFIG_HEADERS’ but flattened if passed
     via ‘@DEFS@’ (with no effect on the compilation, since the
     preprocessor sees only one line in the first place).  VALUE should
     not contain raw newlines.  If you are not using
     ‘AC_CONFIG_HEADERS’, VALUE should not contain any ‘#’ characters,
     as ‘make’ tends to eat them.  To use a shell variable, use
     ‘AC_DEFINE_UNQUOTED’ instead.

     DESCRIPTION is only useful if you are using ‘AC_CONFIG_HEADERS’.
     In this case, DESCRIPTION is put into the generated ‘config.h.in’
     as the comment before the macro define.  The following example
     defines the C preprocessor variable ‘EQUATION’ to be the string
     constant ‘"$a > $b"’:

          AC_DEFINE([EQUATION], ["$a > $b"],
            [Equation string.])

     If neither VALUE nor DESCRIPTION are given, then VALUE defaults to
     1 instead of to the empty string.  This is for backwards
     compatibility with older versions of Autoconf, but this usage is
     obsolescent and may be withdrawn in future versions of Autoconf.

     If the VARIABLE is a literal string, it is passed to
     ‘m4_pattern_allow’ (*note Forbidden Patterns::).

     If multiple ‘AC_DEFINE’ statements are executed for the same
     VARIABLE name (not counting any parenthesized argument list), the
     last one wins.

 -- Macro: AC_DEFINE_UNQUOTED (VARIABLE, VALUE, [DESCRIPTION])
 -- Macro: AC_DEFINE_UNQUOTED (VARIABLE)
     Like ‘AC_DEFINE’, but three shell expansions are
     performed--once--on VARIABLE and VALUE: variable expansion (‘$’),
     command substitution (‘`’), and backslash escaping (‘\’), as if in
     an unquoted here-document.  Single and double quote characters in
     the value have no special meaning.  Use this macro instead of
     ‘AC_DEFINE’ when VARIABLE or VALUE is a shell variable.  Examples:

          AC_DEFINE_UNQUOTED([config_machfile], ["$machfile"],
            [Configuration machine file.])
          AC_DEFINE_UNQUOTED([GETGROUPS_T], [$ac_cv_type_getgroups],
            [getgroups return type.])
          AC_DEFINE_UNQUOTED([$ac_tr_hdr], [1],
            [Translated header name.])

   Due to a syntactical oddity of the Bourne shell, do not use
semicolons to separate ‘AC_DEFINE’ or ‘AC_DEFINE_UNQUOTED’ calls from
other macro calls or shell code; that can cause syntax errors in the
resulting ‘configure’ script.  Use either blanks or newlines.  That is,
do this:

     AC_CHECK_HEADER([elf.h],
       [AC_DEFINE([SVR4], [1], [System V Release 4]) LIBS="-lelf $LIBS"])

or this:

     AC_CHECK_HEADER([elf.h],
       [AC_DEFINE([SVR4], [1], [System V Release 4])
        LIBS="-lelf $LIBS"])

instead of this:

     AC_CHECK_HEADER([elf.h],
       [AC_DEFINE([SVR4], [1], [System V Release 4]); LIBS="-lelf $LIBS"])